local-name()-Funktion  
Diese Funktion liefert den Lokalteil des ersten Knotens der Knotenmenge im Argument.
 
Eingaben

Eine Knotenmenge. Ist die Knotenmenge leer, gibt die Funktion einen leeren String zurück. Wird keine Knotenmenge angegeben, verwendet die Funktion eine Knotenmenge, deren einziger Inhalt der Kontextknoten ist.
 
Ausgabe

Ein String, der dem lokalen Namen des ersten Elements in der Knotenmenge im Argument entspricht. Ist die Knotenmenge leer, gibt die Funktion local-name()einen leeren String zurück.

 
Definition

XPath-Abschnitt 4.1, Funktionen auf Knotenmengen

 
Beispiel

Hier ein Stylesheet, das die Funktion document() dazu verwendet, alle seine eigenen Knoten zu verarbeiten. Anschließend wird für jeden Knoten die Funktion local-name() aufgerufen.

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:months="Lookup table for month names">

  <months:name sequence="12">December</months:name>
  <months:name sequence="01">January</months:name>
  <months:name sequence="02">February</months:name>
  <months:name sequence="03">March</months:name>
  <months:name sequence="04">April</months:name>
  <months:name sequence="05">May</months:name>
  <months:name sequence="06">June</months:name>
  <months:name sequence="07">July</months:name>
  <months:name sequence="08">August</months:name>
  <months:name sequence="09">September</months:name>
  <months:name sequence="10">October</months:name>
  <months:name sequence="11">November</months:name>

  <xsl:output method="text"/>

  <xsl:variable name="newline">
<xsl:text>
</xsl:text>
  </xsl:variable>

  <xsl:template match="/">
    <xsl:value-of select="$newline"/>
    <xsl:text>A test of the local-name() function:</xsl:text>

    <xsl:value-of select="$newline"/>
    <xsl:value-of select="$newline"/>
    <xsl:for-each select="document('')//*">
      <xsl:text>local-name: </xsl:text>
      <xsl:value-of select="local-name()"/>
      <xsl:value-of select="$newline"/>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

Das Stylesheet erzeugt die folgenden Ergebnisse:


A test of the local-name() function:

local-name: stylesheet
local-name: name
local-name: name
local-name: name
local-name: name
local-name: name
local-name: name
local-name: name
local-name: name
local-name: name
local-name: name
local-name: name
local-name: name
local-name: output
local-name: variable
local-name: text
local-name: template
local-name: value-of
local-name: text
local-name: value-of
local-name: value-of
local-name: for-each
local-name: text
local-name: value-of
local-name: value-of